En este video muestro como armar una galería de imágenes al estilo Picasa usando un XML y JPGs externos.
También vemos como asignar clases a elementos de la libreria e interactuar con ellos y las clases.

Nuevo Video: Creando una Galería de imágenes estilo Picasa

También te puede interesar:

• Carga Externa de XML con AS3 (Video Tutorial)
• Menú dinámico en XML y ActionScrip 3
• Nuevo Video Tutorial – SWFAddress 2 con AS3
• Cargar SWF externo en AS3 (Video Tutorial)
• Efecto RollOver con AS3 (Video Tutorial)

En un proyecto que estoy desarrollando en PaperVision3D surgió la necesidad de implementar input text para un formaulario, el cual esta en un material de un cubo.

Para los que tiene una idea de PaperVision3D saben que los cubo llevan un MaterialList, con 6 matriales distintos. Uno para cada cara del cubo.

En uno de ellos decidimos colocar un formaulario, que obviamente tiene muchos campos de texto para ser completados. Pero a la hora de hacer las pruebas me percaté que al hacer click sobre los campos no se activan para escribir en ellos. La solución a este problema es muy sencilla, pero tal ves, como pasa con las cosas sencillas, no es facil darse cuenta de la solución, por mas obvia que sea.

Lo que hay que hacer es agregarle un addListener a cada campo y en el metodo que llamamos con el listener reasiganar el foco del stage al mismo campo, como muestro a continuación.

1
2
3
4
5
6

texto_txt.addEventListener(MouseEvent.CLICK, onClickInput);
 
private function onClickInput(e:MouseEvent):void
{
     stage.focus = e.target;
}

El problema que tenemos con está técnica es que no podemos clickear y arrastrar para seleccionar una porción del texto, como tampoco podemos hacer click en el medio de una palabra para que el el cursor quede allí. El cursor siempre quedará al final del texto.

No es lo más comodo, pero si necesitamos usar un input text en un material de PaperVision3D creo que es una buena solución.

También te puede interesar:

• Como funciona BasicView de PaperVision 3D 2.0
• Carrusel 3d con PV3D (Video Tutorial)
• PaperVision3D, paquete de clases 3D para flash
• Nuevo Video: Creando una Galería de imágenes estilo Picasa
• Realidad Aumentada, una realidad en aumento

Esta es una herramienta que uso hace bastante tiempo, y hace rato quiero escribir sobre ella. Hoy es el día.
De MonsterDebugger es, como el título lo dice, un debugger open source para Flash, Flex y AIR desarrollado por el estudio De Monsters en Flex y AIR.

Con esta herramienta podemos hacer trace de cadenas, números, objetos, matrices, XML e incluso clases personalizadas.

Una de las características que más uso, y creo más útil es la del “trace en vivo”, que nos permite ver los trace del debugger en nuestra aplicación o página corriendo fuera del flash.
Esta utilidad es excelente para hacer pruebas online o para tener el registro de errores sin necesidad de abrir el flash y ver qué pasa.

Otra característica interesante del debugger es poder modificar propiedades de nuestro proyecto en tiempo de ejecución. O sea, mientras vemos nuestra página ya publicada, podemos desde el panel del debugger, cambiar las propiedades que queramos, como rotación, tamaño o la variable que queramos y ver su efecto en vivo y en directo. Algo útil e interesante.

También, siguiendo con las acciones en vivo, podemos ejecutar nuestras funciones o métodos para probarlas en cualquier momento mientras vemos el proyecto ya compilado, también extremadamente útil.

¿Cómo funciona:
Les dejo 4 pasos básicos publicados en la página del debugger para empezar a usarlo.

1. En primer lugar es necesario tener Adobe AIR instalado.
2. Una vez descargado De MonsterDebugger basta con abrir la descarga y AIR hará el resto.
3. Una vez que esté funcionando De MonsterDebugger, necesita importar las clases de cliente para establecer la conexión con De MonsterDebugger. Las clases de cliente está incorporado en De MonsterDebugger y se pueden guardar en cualquier ubicación seleccionando Archivo> Exportar cliente de clase. Guarde la carpeta en la carpeta raíz de su aplicación o donde tengas tus clases.
4. Ahora todo lo que tiene que hacer es importar la clase en tu proyecto. A continuacion ejemplos de Flash y Flex.

Ejemplo Flash:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21

package {
 
	import flash.display.Sprite;
        // Importamos el debugger
	import nl.demonsters.debugger.MonsterDebugger;
 
	public class Main extends Sprite {
 
		// creamos la instancia del debugger
		private var debugger:MonsterDebugger;
 
		public function Main() {
 
			// iniciamos el debugger
			debugger = new MonsterDebugger(this);
 
			// enviamos un simple trace
			MonsterDebugger.trace(this, "Hello World!")
		}
	}
}

Ejemplo Flex:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" initialize="init()">
	<mx:Script>
		<![CDATA[
 
		// Importamos el debugger
		import nl.demonsters.debugger.MonsterDebugger;
 
		// creamos la instancia del debugger
		private var debugger:MonsterDebugger;
 
		private function onInit():void
		{
			// iniciamos el debugger
			debugger = new MonsterDebugger(this);
 
			// enviamos un simple trace
			MonsterDebugger.trace(this, "Hello World!");
		}
		]]>
	</mx:Script>
</mx:Application>

Link: De MonsterDebugger
Descarga: MonsterDebugger version 2.5.1 (incluye ejemplos)

También te puede interesar:

• Prerelease del SDK de Adobe AIR para Android
• Componentes para flash gratis
• Nuevas características que tendrá Adobe Flash CS5
• Text Layout Framework (TLF)
• 3D nativo en Flash Player 11, Adobe seguirá nutriendo la web

Usar Google Map con ActionScript 3

En este video mostramos como agregar Google Map en nuestro proyecto con ActionScript 3, usando el API que Google nos proporciona.
Vemos como agregar los controles del mapa y como agregar una marca.

También te puede interesar:

• Nuevo Video: Creando una Galería de imágenes estilo Picasa
• Como funciona BasicView de PaperVision 3D 2.0
• Menú dinámico en XML y ActionScrip 3
• Nuevo Video Tutorial – SWFAddress 2 con AS3
• Cargar SWF externo en AS3 (Video Tutorial)

En este tutorial quiero mostrarles como funciona la clase BasicView de PaperVision 3D 2.0.
Esta clase nos facilita muchisimo a la hora de empezar un nuevo proyecto con esta herramienta.

En proyectos de PV3D se repiten siempre varias acciones, como importar clases básicas como Camera, Scene, Viewport, etc.
También repetimos la creacion de funciones que son si o si necesarias. Como la que renderize nuestra escena en un enterFrame o la que inicie todo los objetos. Por eso, la gente de PV3D decidió acertadamente crear esta clase incluida en la versión 2.0. que se puede extender en cualquier clase y nos ahorra todos esos pasos comentados.

Acá les dejo un ejemplo de como se usaría, explicando en los comentarios algunos detalles:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26

package {
    import flash.events.Event;
    import org.papervision3d.view.BasicView; // importamos la clase
 
    public class ClasePrueba extends BasicView // extendemos nuestra clase a BasicView
    {
        public function ClasePrueba ()
        {
            stage.frameRate = 40; //seteamos los cuadros por segundos.
            init(); // este metodo inicia todos los elementos.
            startRendering(); // comenzamos a renderizar.
        }
 
        private function init():void
        {
            // dentro de este metodo creamos todos los elemento 3d y demás cosas antes de empezar a renderizar.
        }
 
        override protected function onRenderTick(e:Event=null):void
        {
            // este metodo lo reescribimos sobre el de BasicView, por eso usamos "override protected".
            // todo lo que pongamos dentro de este metodo sería como un EnterFrame, o sea podemos mover nuestros objetos desde aquí
            super.onRenderTick(); // es necesario llamar al super de la clase.
        }
    }
}

Espero quede claro, cualquier consulta pueden usar los comentarios o el twitter.
De a poco voy a ir agregando nuevas cosas sobre PV3D.

Saludos

También te puede interesar:

• PaperVision3D, paquete de clases 3D para flash
• Nuevo Video: Creando una Galería de imágenes estilo Picasa
• Usando Input text con PaperVision3D
• Realidad Aumentada, una realidad en aumento
• Usar Google Map con ActionScript 3

La semana pasada subí una clase para mostrar texto en ActionScript2 (txtRandom) de forma random con cada caracter.
Esta semana tuve que desarrollar otrá clase que también sirve para mostrar texto, pero al estilo máquina de escribir, algo muy utilizado.
La gran diferencia con la demás clases que hacen lo mismo es que esta reescribe sobre lo que ya estaba escrito, sin empezar de cero.

Acá va la clase completa, que al igual que la Clase txtRandom es estática, así es más simple de utilizar.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

class txtTiper
{
	static private var animaciones:Array = new Array();
 
	function txtTiper()
	{
	}
 
	static public function setText(_trg, _txt:String, _comodin:String):Void
	{
		for (var i:Number = 0; i < animaciones.length; i++) {
			if (_trg == animaciones[i]) {
				var flag = true;
				var tmp = animaciones[i];
			}
		}
		if (!flag) {
			var tmp = animaciones[animaciones.length] = _trg;
		}
 
		tmp.strArray = new Array();
		tmp.buffer = '';
		tmp.originalStr = _txt;
		tmp.comodin = _comodin;
		tmp.textoArr = splitStr(tmp);
		tmp.autoSize=true
		tmp.html=false
		tmp.strBuffer = tmp.text.substr(0, tmp.text.length - 1);
 
		clearInterval(tmp.fInt);
		tmp.fInt = setInterval(eFrame, 50, tmp);
	}
 
	static public function splitStr(_tmp) {
		for (var i=0; i<=_tmp.originalStr.length; i++) {
			_tmp.strArray.push(_tmp.originalStr.charAt(i));
		}
	}
 
	static public function eFrame(_tmp):Void
	{
		if (_tmp.text == _tmp.originalStr + _tmp.comodin) {
			_tmp.text = _tmp.originalStr;
			_tmp.strBuffer = _tmp.originalStr;
			clearInterval(_tmp.fInt);
			return;
		}
 
		var tmpstr = '';
		if (_tmp.strBuffer.length > 0) {
			_tmp.strBuffer = _tmp.strBuffer.substr(1, _tmp.strBuffer.length - 1);
		}else{
			_tmp.strBuffer = "";
		}
 
		if (_tmp.strArray.length > 0) {
			var newElement = _tmp.strArray.shift();
			_tmp.buffer += newElement;
			tmpstr += _tmp.buffer + _tmp.comodin;
		} else {
			tmpstr = _tmp.originalStr + _tmp.comodin;
		}
 
		_tmp.text = tmpstr + _tmp.strBuffer;
	}
}

Con solo estas dos lineas ya anda nuestro proyecto.

1
2

import txtTiper;
txtTiper.setText(prueba_txt, "texto a mostrar", "|");

1º parámetro: el nombre de instancia del Textfiled a usa.
2º parámetro: el texto a mostrar.
3º parámetro: el comodín o caracter que va al final del texto al escribirse.

Espero les sirva y guste.

También te puede interesar:

• txtRandom – Clase para mostrar textos en AS2
• Incrustar Flash con SWFObject 2.0 (Video Tutorial)
• Nueva Interpolación de Movimiento en Flash CS4 (Video Tutorial)
• Rápido recorrido por la interface Flash CS4 (Video Tutorial)
• Flash Básico – Interface (Video Tutorial)

Hace unos días desarrollé esta simple clase para mostrar textos cortos en un proyecto de AS2.

El efecto que busqué fue mostrar cada caracter de la frase con un random de caracteres (efecto ya muy común). Pero a diferencia de los demás que hay por todos lados esta clase hace un random de que caracter empieza a mostrar en distintas posiciones y no del primero al último.

Para que se entienda mejor acá hay un SWF con la muestra. Cada 3 segundos se reinicia el efecto para que puedan verlo bien.

Acá va la clase entera.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86

class txtRandom
{
	static var alfabetos:Array;
	static var animaciones:Array = new Array();
 
	function txtRandom(){}
 
	static public function crearAlfabetos():Void
	{
		alfabetos = new Array();
		alfabetos[0] = "qwertyuiopasdfghjklzxcvbnm";
		alfabetos[1] = "1234567890";
		alfabetos[2] = "!@#$%^7*()+<>/?[]{}\|";
		alfabetos[3] = "qwertyuiopasdfghjklzxcvbnm1234567890";
		alfabetos[4] = "qwertyuiopasdfghjklzxcvbnm1234567890!@#$%^7*()+<>/?[]{}\|";
	}
 
	static public function setText(_trg, _txt:String, _comodin:String, _alf:Number, _rndTime:Number, _ltrTime:Number):Void
	{
		crearAlfabetos();
		for (var i:Number = 0; i < animaciones.length; i++) {
			if (_trg == animaciones[i]) {
				var flag = true;
				var tmp = animaciones[i];
			}
		}
		if (!flag) {
			var tmp = animaciones[animaciones.length] = _trg;
		}
		tmp.alf = _alf;
		tmp.texto = _txt;
		tmp.comodin = _comodin;
		tmp.rndTime = _rndTime;
		tmp.ltrTime = _ltrTime;
		tmp.textoArr = _txt.split("");
		tmp.estadoArr = [];
		tmp.actualArr = [];
		tmp.posArr = [];
		tmp.pos = 0;
		tmp.fin = 1;
		tmp.finalizados = 0;
		tmp.todos = 0;
 
		for (var i:Number = 0; i < tmp.textoArr.length; i++) {
			tmp.estadoArr[i] = 0;
			tmp.actualArr[i] = tmp.comodin;
		}
 
		clearInterval(tmp.sInt);
		clearInterval(tmp.nInt);
		clearInterval(tmp.fInt);
		tmp.sInt = setInterval(eFrame, 50, tmp);
		tmp.nInt = setInterval(ltrInterval, tmp.ltrTime * 1000, tmp);
		tmp.fInt = setInterval(finInterval, tmp.rndTime * 1000, tmp);
	}
 
	static public function eFrame(_tmp):Void
	{
		_tmp.text = _tmp.actualArr.join("");
 
		for (var i:Number = 0; i < _tmp.estadoArr.length; i++) { 			if(_tmp.estadoArr[i] == 1){ 				_tmp.actualArr[i] = alfabetos[_tmp.alf].charAt(random(alfabetos[_tmp.alf].length)); 			} 		} 	} 	 	static public function ltrInterval(_tmp):Void 	{ 		var rndL:Number = random(_tmp.estadoArr.length); 		if(_tmp.todos == _tmp.estadoArr.length-1){ 			clearInterval(_tmp.nInt); 		} 		if(_tmp.estadoArr[rndL] > 0){
			ltrInterval(_tmp);
		}else{
			_tmp.pos++;
			_tmp.posArr[rndL] = _tmp.pos;
			_tmp.estadoArr[rndL] = 1;
			_tmp.todos++;
		}
	}
 
	static public function finInterval(_tmp):Void
	{
		if(_tmp.finalizados == _tmp.estadoArr.length){
			clearInterval(_tmp.fInt);
			clearInterval(_tmp.sInt);
		}
		for (var i:Number = 0; i < _tmp.posArr.length; i++) {
			if(_tmp.posArr[i] == _tmp.fin){
				_tmp.estadoArr[i] = 2;
				_tmp.actualArr[i] = _tmp.textoArr[i];
				_tmp.fin++;
				_tmp.finalizados++;
			}
		}
	}
}

La clase esta hecha de forma estática así nos ahorramos el hecho de crear instancias. Otra característica de la clase es que guarda todas las propiedades de la animación el objeto del texto dinámico, y los objetos a su vez en un array para poder controlarlos por separado sin que se pisen los efectos.

el array llamado “alfabetos” contiene distintos String que nos permitira elegir desde el método setText. Estos textos son usados para hacer el random de letras. Mostrando únicamente los caracteres que esten en el alfabeto elegído.

Para usarla solo hace falta escribir un código como este:

1
2

import txtRandom;
txtRandom.setText(texto_txt, "DeCabeza.net", "-", 4, .5, .2);

El método setText puede llamarse todas las veces que se quiera y para distintos elementos. Paso a explicar los parametros del metodo.

1º parámetro: el nombre del texto dinámico.
2º parámetro: el texto a mostrar.
3º parámetro: el caracter por default, puede estar vacio (pero si van las comillas).
4º parámetro: la posición del array de “alfabetos”.
5º parámetro: los segúndos que tarda desde que empieza el random de caracteres de cada letra hasta mostrar la final.
6º parámetro: el tiempo que tarda en segúndos en empezar cada caracter.

Espero les sea útil. Saludos!

Ejemplo y Clase:  txtRandom.zip

También te puede interesar:

• txtTiper – otra Clase para mostrar textos en ActionScript2
• Incrustar Flash con SWFObject 2.0 (Video Tutorial)
• Nueva Interpolación de Movimiento en Flash CS4 (Video Tutorial)
• Rápido recorrido por la interface Flash CS4 (Video Tutorial)
• Flash Básico – Interface (Video Tutorial)

Menú dinámico en XML y ActionScrip 3

Con este nuevo video tutorial vamos a aprender a crear un menú dinámico desde un xml con ActionScript 3.
De esta forma podemos cambiar el contenido del menú editando el .xml y sin la necesidad de compilar nuevamente nuestro .fla.
Agregando, quitando o modificando la cantidad de botones.

Algo muy útil y que sirve de base para muchas otras aplicaciones del mismo método.

Espero les sirva, cualquier cosa pueden comentar, preguntar o criticar.

También te puede interesar:

• Nuevo Video: Creando una Galería de imágenes estilo Picasa
• Carga Externa de XML con AS3 (Video Tutorial)
• Usar Google Map con ActionScript 3
• Como funciona BasicView de PaperVision 3D 2.0
• Nuevo Video Tutorial – SWFAddress 2 con AS3

Nuevo Video Tutorial – SWFAddress 2 con AS3

En este nuevo video explicamos como usar la libreria de Flash y AJAX SWFAddress, que nos permite tener una navegación de nuestro proyecto usando los botones de siguiente y anterior del navegador y al mismo tiempo cambiando la URL según la sección o estado del flash en el que estemos.

Es muy útil para proyectos en los que se quiera que el usuario pueda ingresar a contenidos determinados directamente. Y además permite un indexado mucho mejor de un proyecto integro en Flash.
Espero les sirva y cualquier recomendación pueden comentar acá o en el topic del foro correspondiente.

También te puede interesar:

• Nuevo Video: Creando una Galería de imágenes estilo Picasa
• Cargar SWF externo en AS3 (Video Tutorial)
• Carga Externa de XML con AS3 (Video Tutorial)
• Efecto RollOver con AS3 (Video Tutorial)
• Usar Google Map con ActionScript 3

Incrustar Flash con SWFObject 2.0 (Video Tutorial)

En este video veremos como incrustar o embeber un swf en un html con el script de SWFObject 2.0.

También te puede interesar:

• Nueva Interpolación de Movimiento en Flash CS4 (Video Tutorial)
• Rápido recorrido por la interface Flash CS4 (Video Tutorial)
• Flash Básico – Interface (Video Tutorial)
• Nuevo Video: Creando una Galería de imágenes estilo Picasa
• txtTiper – otra Clase para mostrar textos en ActionScript2

Cargar SWF externo en AS3 (Video Tutorial)

Con este video vamos a aprender como cargar un SWF externo con AS3 en nuestra pélicula usando un preloader.

También te puede interesar:

• Nuevo Video: Creando una Galería de imágenes estilo Picasa
• Nuevo Video Tutorial – SWFAddress 2 con AS3
• Carga Externa de XML con AS3 (Video Tutorial)
• Efecto RollOver con AS3 (Video Tutorial)
• Usar Google Map con ActionScript 3

Nueva Interpolación de Movimiento en Flash CS4 (Video Tutorial)

Flash CS4 cuenta con un nuevo sistema de animación. En este video vamos a ver algúnas de las novedades.

También te puede interesar:

• Incrustar Flash con SWFObject 2.0 (Video Tutorial)
• Rápido recorrido por la interface Flash CS4 (Video Tutorial)
• Flash Básico – Interface (Video Tutorial)
• Nuevo Video: Creando una Galería de imágenes estilo Picasa
• txtTiper – otra Clase para mostrar textos en ActionScript2

Rápido recorrido por la interface Flash CS4 (Video Tutorial)

A través de este video vamos a hacer una rápida recorrida de la nueva interface del Flash CS4.

También te puede interesar:

• Incrustar Flash con SWFObject 2.0 (Video Tutorial)
• Nueva Interpolación de Movimiento en Flash CS4 (Video Tutorial)
• Flash Básico – Interface (Video Tutorial)
• Nuevo Video: Creando una Galería de imágenes estilo Picasa
• txtTiper – otra Clase para mostrar textos en ActionScript2

Flash Básico – Interface (Video Tutorial)

Este es el primero de una serie de Video Tutoriales que tengo pensado hacer sobre Flash.
Comenzando por lo más básico, como en este caso con la interface, hasta llegar a ejemplos más avanzados de ActionScript.
Decido comenzar con estos videos, por la sugerencia de un colega, Nico Santos, quien me recomendo hacer videos más cortos
y con contenidos básico. Así de esta froma ir avanzando con videos avanzados y sin tener la necesidad de explicar tanto en cada video.

Espero les sirva aunque es bien bien bien baaaasico.
Saludos!

También te puede interesar:

• Incrustar Flash con SWFObject 2.0 (Video Tutorial)
• Nueva Interpolación de Movimiento en Flash CS4 (Video Tutorial)
• Rápido recorrido por la interface Flash CS4 (Video Tutorial)
• Nuevo Video: Creando una Galería de imágenes estilo Picasa
• txtTiper – otra Clase para mostrar textos en ActionScript2

Este es un efecto muy utilizado en varios tipos de desarrollo. Como puede ser en un catálogo de productos, ejemplo clásico si los hay.
Se me ocurrió armar una clase en AS3 para esta utilidad, a modo de simplificar el trabajo.
De paso les dejo una hermosa imagen del calendario Maya. Gran civilización si las hubo!

Mové el mouse sobre la imagen para ver el efecto.

A continuación les dejo la clase completa. Vale destacar los cuatro métodos con namespace en “protected”.
Estos métodos pueden ser reescritos si la clase es extendida… De manera tal que se puedan manejar los eventos de progreso de carga, y de la carga completa. Para poder sumarle un preloader tanto a la imagen chica, como a la grande por ejemplo.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129

package weedo.fx {
 
import flash.display.DisplayObject;
import flash.display.Sprite;
import flash.display.Loader;
import flash.events.*;
import flash.net.URLRequest;
import flash.ui.Mouse;
 
public class Lupa extends Sprite
{
     private var imgURL:String;
     private var imgBigURL:String;
     private var mascara:DisplayObject;
     private var small:Sprite;
     private var big:Sprite;
     private var cargaCompleta:Boolean;
 
     public function Lupa(_imgURL:String, _imgBigURL:String, _mask:DisplayObject):void
     {
          imgURL = _imgURL;
          imgBigURL = _imgBigURL;
          mascara = _mask;
 
          this.mouseChildren = false;
          this.addEventListener(MouseEvent.MOUSE_MOVE, onMove);
          this.addEventListener(MouseEvent.ROLL_OUT, onOut);
          this.addEventListener(MouseEvent.ROLL_OVER, onOver);
 
          cargarImg();
     }
 
     private function cargarImg():void
     {
          var loaderImg:Loader = new Loader();
          loaderImg.contentLoaderInfo.addEventListener(Event.COMPLETE, onCompleteImg);
          loaderImg.contentLoaderInfo.addEventListener(Event.INIT, onInitImg);
          loaderImg.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, onProgressImg);
          loaderImg.load(new URLRequest(imgURL));
     }
 
     private function cargarImgBig():void
     {
          var loaderImgBig:Loader = new Loader();
         loaderImgBig.contentLoaderInfo.addEventListener(Event.COMPLETE, onCompleteImgBig);
          loaderImgBig.contentLoaderInfo.addEventListener(Event.INIT, onInitImgBig);
          loaderImgBig.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, onProgressImgBig);
          loaderImgBig.load(new URLRequest(imgBigURL));
     }
 
     protected function onProgressImg(e:ProgressEvent):void
     {
          trace("img: "+Math.round((e.bytesLoaded*100)/e.bytesTotal));
     }
     protected function onProgressImgBig(e:ProgressEvent):void
     {
          trace("imgBig: "+Math.round((e.bytesLoaded*100)/e.bytesTotal));
     }
     protected function onInitImg(e:Event):void
     {
          trace("termino img");
     }
     protected function onInitImgBig(e:Event):void
     {
          trace("termino imgBig");
     }
 
     private function onCompleteImg(e:Event):void
     {
          small = new Sprite();
          e.target.content.x = -(e.target.content.width*.5);
          e.target.content.y = -(e.target.content.height*.5);
          small.addChild(e.target.content);
 
          addChild(small);
          cargarImgBig();
     }
 
     private function onCompleteImgBig(e:Event):void
     {
          big = new Sprite();
          e.target.content.x = -(e.target.content.width*.5);
          e.target.content.y = -(e.target.content.height*.5);
          big.addChild(e.target.content);
          big.mask = mascara;
          big.visible = false;
 
          addChild(big);
          addChild(mascara);
          cargaCompleta = true;
     }
 
     private function onMove(e:MouseEvent):void
     {
          if(cargaCompleta){
               mascara.x = mouseX;
               mascara.y = mouseY;
 
               big.x = -((big.width * small.mouseX)/small.width) + small.mouseX;
               big.y = -((big.height * small.mouseY)/small.height) + small.mouseY;
          }
     }
 
     private function onOut(e:MouseEvent):void
     {
          if(cargaCompleta){
               big.visible = false;
               Mouse.show();
          }
     }
 
     private function onOver(e:MouseEvent):void
     {
          if(cargaCompleta){
               big.visible = true;
               Mouse.hide();
          }
     }
 
     public function cambiarMascara(_tg:DisplayObject):void
     {
          if(cargaCompleta){
               mascara = _tg;
               big.mask = mascara;
          }
     }
 
 }
}

Para implementar la clase en el IDE de Flash deberían escribir algo así:

1
2
3
4
5
6
7
8
9
10
11

import weedo.fx.Lupa;
 
var sh:Shape = new Shape();
sh.graphics.beginFill(0x000000,1);
sh.graphics.drawCircle(0, 0, 50);
sh.graphics.endFill();
 
var lp:Lupa = new Lupa("small.jpg", "big.jpg", sh);
lp.x = stage.stageWidth * .5;
lp.y = stage.stageHeight * .5;
addChild(lp);

En este ejemplo importamos la clase en la primer linea. Luego creamos un Shape circular y por último creamos nuestra lupa con sus 3 parametros.
Primero la imagen pequeña, luego la grande y por último la máscara que usaremos como lupa.
En este caso la máscara es un Shape circular. También podría ser un rectangulo y hasta un movieclip con la forma que querramos.
Ojo que el punto de registro siempre tiene que estar en el medio de nuestra máscara.

Por ejemplo si queremos usar un rectangulo, el código debería ser así:

1
2
3
4

var sh:Shape = new Shape();
sh.graphics.beginFill(0x000000,1);
sh.graphics.drawRect(-25, -25, 50, 50);
sh.graphics.endFill();

Fijense como uso el “-25″ para correr el punto de registro.

Bueno espero les sirva, acá les dejo también los archivos del ejemplo:

Archivos del ejemplo

También te puede interesar:

• Nuevo Video: Creando una Galería de imágenes estilo Picasa
• Usar Google Map con ActionScript 3
• Como funciona BasicView de PaperVision 3D 2.0
• Menú dinámico en XML y ActionScrip 3
• Nuevo Video Tutorial – SWFAddress 2 con AS3

Carga Externa de XML con AS3 (Video Tutorial)

En este video tutorial muestro como cargar un XML externo con ActionScript 3. Algo bastante simple, pero necesario para hacer cosas más complejas.
Pido perdón como siempre por el audio, mis colgadas hablando (esta como siempre sin editar) y la informalidad del video.
Para los que les interese el tema pueden profundizar mucho buscando informacion sobre XML, E4X y ECMAScript.

Ojalá les guste y espero comentarios sobre que otros temas básicos de AS3 les gustaría que hiciera videos.

También te puede interesar:

• Nuevo Video: Creando una Galería de imágenes estilo Picasa
• Menú dinámico en XML y ActionScrip 3
• Nuevo Video Tutorial – SWFAddress 2 con AS3
• Cargar SWF externo en AS3 (Video Tutorial)
• Efecto RollOver con AS3 (Video Tutorial)

Carrusel 3d con PV3D (Video Tutorial)

Bien, como prometí, acá les cuelgo el segundo Video Tutorial.
En este caso se trata de como hacer un efecto ya conocido en el mundo de los desarrolladores web. Un carrusel 3d. Pero con la diferencia que en vez de usar pura trigonometría también vamos a usar la librería de Clases llamada PaperVision 3d (PV3D), que ya mensione en otro post.

La calidad de audio y la proligidad del video no es lo mejor, pero me parece más optimo sacar varios videos que se entiendan y no perder tanto tiempo en esos detalles, que a veces evitan que pueda publicar los videos, por falta de tiempo.

A su debido tiempo ire mejorando esos detalles. Así quedan videos más cortos y mejor editados.
Espero les sirva y escriban comentarios y dudas!.

Links:
Sitio de PaperVision 3d
Descargas de PV3D
PV3D 2.0 Beta

También te puede interesar:

• Nuevo Video: Creando una Galería de imágenes estilo Picasa
• Usando Input text con PaperVision3D
• Como funciona BasicView de PaperVision 3D 2.0
• Nuevo Video Tutorial – SWFAddress 2 con AS3
• Incrustar Flash con SWFObject 2.0 (Video Tutorial)

Para comenzar con este tema hay que aclarar que el modelo de renderización de ActionScript 3.0 y Flash Player 9 es muy diferente a las versiones anteriores.

Anteriormente toda película SWF contaba con un MovieClip raíz, llamado escenario o _root desde el código. Estos MC podían contener MC hijos, y a su vez estos tener otros MC hijos dentro. El concepto de profundidad se usaba para controlar el orden de renderización o dibujo de estos elementos para dar la apariencia de estar “encima” o “debajo” de otros elementos.

Antes se usaban metodos muy conocidos como createEmptyMoviClip(), attachMovie(), duplicateMovieClip(), para ordenar y crear estos MC. Siempre que se creaba un nuevo MC este aparecia por encima de los ya existentes. No podían ser movidos a lugares diferentes dentro de las jerarquías existentes, sino que se debían destruir y crear nuevamente. por ejemplo si yo tenia un MC dentro de otro llamado “objeto1″ no podia moverlo a un MC llamado “objeto2″. Debía borrarlo y volver a crearlo dentro del otro MC.

El nuevo sistema de render sigue siendo jerárquico, pero es mucho mas flexible y simple al momento de rendriza. Este nuevo modelo o sistema se centra en lo que se llama “Lista de Visualización” que se encuentra centrado en la clase flash.display.
Esta lista de visualización contiene todos los objetos que hay en nuestro SWF, por lo que cualquier objeto que no se encuetre en esta lista no sera renderizado en nuestra película.

Esta jerarquía se separa en 3 tipos de objetos:
El escenario: es un objeto raíz único de cada película, el cual contiene un solo hijo, la clase de aplicación principal del SWF. Se puede acceder a traves de la propiedad stage.
Contenedores del objeto de visualización: como su nombre lo indica es el objeto encargado de contener los objetos de visualizacion. El escenario sería uno de estos objetos, como también los conocidos MovieClip y el nuevo Sprite. Vale aclarar que si un Contenedor es eliminado, todos sus hijos se eliminan también.
Objetos de visualización: Algunas clases funsionan tanto como objetos de visualización como contenedores, como puede ser el caso del MovieClip, quein contiene pero a la vez puede representarse visualmente.
Hay otras clases como el caso del TextField, que unicamente funsionan como objetos visuales (o sea no pueden contener nuevos objetos como hijos).

una vez explicado esto vamos a pasar a lo que a la mayoría les interesa, los ejemplos.
Como podemos añadir un elemento a nuestra lista de visualización?
La solución es utilizar los nuevos metodos addChild() y addChildAt().

1
2
3

var textoHola:TextField = new TextField();
textoHola.text = "Hola Mundo!";
addChild(textoHola)

Con este ejemplo estamos creando un elemto de texto (TextField) que nos dice “Hola Mundo!”. Si no escribiriamos la última linea, el texto no se mostraria en nuestra película, ya que no fue guardado en la lista de visualización. Por lo tanto, hubiera sido creado en memoria, pero no renderizado.
En este ejemplo estamos agregando el elemento a un Conetenedos, que seria el escenario en si. Tambien podriamos crear un Contenedor (MovieClip, Sprite) e incluir el texto ahi dento.

1
2
3
4
5

var textoHola:TextField = new TextField();
textoHola.text = "Hola Mundo!";
 
var contenedor:Sprite = new Sprite();
addChild(contenedor)

De esta forma tenemos un contendor y un texto como hijo del mismo.

Otro cambio importante es el orden de nuestros elemntos. La lista de visualización, como su nombre lo indica es una lista como cualquier Array. O sea tiene ordenados los elemntos de la posición 0 a la que sea necesario. Por lo tanto si yo creo dos circulos y los agrego al escenario ocuparían las posicones 0 y 1, y si creo un tercero ocuparía la posición 2.
Ahora bien, si yo quisiera que el nuevo circulo este entre el 0 y 1 como hago?. Ahí entra addChildAt().
Veamos un ejemplo y luego lo explico:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29

var rojo:Shape = createCircle(0xff0000, 10);
rojo.x = 10;
rojo.y = 20;
var verde:Shape = createCircle(0x00ff00, 10);
verde.x = 15;
verde.y = 25;
var azul:Shape = createCircle(0x0000ff0, 10);
azul.x = 20;
azul.y = 20;
 
// hasta acá creamos en memoria los circulos, pero no son renderizados.
 
addChild(rojo);
addChild(azul);
 
// acá ingresamos en la lista de visualización el circulo rojo y azul, por lo tanto rojo es 0 y azul es 1.
 
addChildAt(verde, 1);
 
// por último ingresamos en la lista a circulo verde, pero en la posición 1 como se ven en los parametros, por lo que desplaza al circulo azul, que estaba en 1 a la posición 2.
 
// createCircle sería un metodos para dibujar los circulos
function createCircle (color:uint, radio:Number):Shape{
var shape:Shape = new Shape();
shape.graphics.beginFill(color);
shape.graphics.drawCircle(0,0,radio);
shape.graphics.endFill();
return shape;
}

Como se explica en el código cuando un elemento es ingresado en una posición ya utilizada, corre todos los demás elemento una posición hacia “arriba”. Esto es muy util y bueno, ya que no es necesario como antes poner un elemento en un nivel 1 y otros en 20, para dejar espacio por las dudas en el medio. Por lo tanto de esta forma tenemos la lista con las posicones necesarias y ordenadas pefectamente sin numeros salteados.

Para eliminar un objeto se utiliza el metodo removeChild() y removeChildAt() de una manera muy simple.

1
2
3
4
5
6
7

//creamos el elemento.
var textoHola:TextField = new TextField();
textoHola.text = "Hola Mundo!";
addChild(textoHola);
 
// lo eliminamos
removeChild(textoHola);

Obviamente si ejecutamos este código, no se verá nada, ya que el elemento se crea y elimina en el momento.
Con removeChild() debemos pasarle como parametro el nombre del objeto creado. En cambio con removeChildAt(), lo que pasamos como parametro es la posición dentro de la lista de visualización. Por ejemplo:

1
2
3
4
5
6
7
8
9
10
11

//creamos los elementos.
var texto1:TextField = new TextField();
texto1.text = "Hola Mundo 1!";
addChild(texto1);
 
var texto2:TextField = new TextField();
texto2.text = "Hola Mundo 2!";
addChild(texto2);
 
// eliminamos el primer texto
removeChildAt(0);

Ahora bien veamos como podemos mover un elemento de un lugar a otro. Esto es muy simple y se hace con el metodo setChildIndex(). Y con la ayuda de los metodos getChildIndex() y getChildAt() para saber la posción de los elementos. Por ejemplo:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25

var rojo:Shape = createCircle(0xff0000, 10);
rojo.x = 10;
rojo.y = 20;
var verde:Shape = createCircle(0x00ff00, 10);
verde.x = 15;
verde.y = 25;
var azul:Shape = createCircle(0x0000ff0, 10);
azul.x = 20;
azul.y = 20;
 
addChild(rojo);
addChild(azul);
addChild(verde);
 
//ahora movemos el circulo verde atras de todo
setChildIndex(verde, 0);
 
// createCircle sería un metodos para dibujar los circulos
function createCircle (color:uint, radio:Number):Shape{
var shape:Shape = new Shape();
shape.graphics.beginFill(color);
shape.graphics.drawCircle(0,0,radio);
shape.graphics.endFill();
return shape;
}

De esta forma el ciruclo verde que estaba adelante de todo pasa al fondo, desplazando todos los demás una posición hacia adelante.
Ahora bien si queremos moverlo a la posción del medio, o sea del circulo azul y no sabemos el número de posición, podemos hacer lo siguiente:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25

var rojo:Shape = createCircle(0xff0000, 10);
rojo.x = 10;
rojo.y = 20;
var verde:Shape = createCircle(0x00ff00, 10);
verde.x = 15;
verde.y = 25;
var azul:Shape = createCircle(0x0000ff0, 10);
azul.x = 20;
azul.y = 20;
 
addChild(rojo);
addChild(azul);
addChild(verde);
 
//ahora movemos el circulo verde atras de todo
setChildIndex(verde, getChildIndex(azul));
 
// createCircle sería un metodos para dibujar los circulos
function createCircle (color:uint, radio:Number):Shape{
var shape:Shape = new Shape();
shape.graphics.beginFill(color);
shape.graphics.drawCircle(0,0,radio);
shape.graphics.endFill();
return shape;
}

Donde getChildIndex(azul) nos devolvería el número de posición del elemento llamado azul.

Nos quedaría ver el metodos getChildAt() el cual nos devuelve a traves de un número pasado como parametro el nombre de un elemnto.
Podemos usarlo en un ejemplo donde pasamos el elemento que esta atras de todo para adelante de todo. Veamos:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25

var rojo:Shape = createCircle(0xff0000, 10);
rojo.x = 10;
rojo.y = 20;
var verde:Shape = createCircle(0x00ff00, 10);
verde.x = 15;
verde.y = 25;
var azul:Shape = createCircle(0x0000ff0, 10);
azul.x = 20;
azul.y = 20;
 
addChild(rojo);
addChild(azul);
addChild(verde);
 
//ahora movemos el circulo rojo adelante de todo
setChildIndex(getChildAt(0), numChildren -1);
 
// createCircle sería un metodos para dibujar los circulos
function createCircle (color:uint, radio:Number):Shape{
var shape:Shape = new Shape();
shape.graphics.beginFill(color);
shape.graphics.drawCircle(0,0,radio);
shape.graphics.endFill();
return shape;
}

En este ejemplo a trasves de getChildAt(0) obtenemos el nombre “rojo”, el cual movemos a la ultima posición, la cual obtenemos con el metodos numChildren – 1 (ya que la primera es 0).

Es un tema muy extenso que intente resumirlo lo mejor posible, así que espero les sirva un poco esto y cualquier duda escriban en los comentarios.

Fuente de inspiración: Libro ActionScript 3.0 para desarrolladores Flash.

También te puede interesar:

• Nuevo Video: Creando una Galería de imágenes estilo Picasa
• Usar Google Map con ActionScript 3
• Como funciona BasicView de PaperVision 3D 2.0
• Menú dinámico en XML y ActionScrip 3
• Nuevo Video Tutorial – SWFAddress 2 con AS3

Vale aclarar antes de comenzar, que esto no es un resumen de OOP (Programación Orientada a Objetos), sino de como se aplica y se usa esta forma de programar con AS3 en el IDE de Flash CS3. Por lo que se tiene que tener una idea de lo que es OOP.

Introducción:
ActionScript 3 nos permite seguir programando en la linea de tiempo como lo haciamos con AS2, pero es mucho más eficiente y profesional usarlo a través de Clases.
En AS todos los objetos nativos de Flash son Clases u Objetos (el objeto en si es una instancia de una Clase), por ejemplo MovieClip, TextField, MovieClipLoader, etc.
La idea de trabajar con Clases es generar nuestras propias Clases, como podría ser una Clase BotonSimple.as (como ejemplo simple), o una Clase GaleriaDeFotos.as (como ejemplo mas complejo), la cual seguramente usaría otras Clases más simples.

Ubicación de las Clases:
La Clases pueden estar ordenada dentro de carpetas y subcarpetas, las cuales suelen llamarse paquetes, estos paquetes nos permiten organizarnos de manera prolija, por ejemplo para un proyecto de mi pagina decabeza.net tendria organizado el paquete de una forma donde tendria la carpeta net, dentro la carpeta decabeza y dentro de esta carpetas, fx (donde por ejemplo guardaria las clases de efectos especiales), text (donde guardaria las clases de efectos y utilidades de textos) y utils (donde guardaria las clases de utilidades en general, como preloaders, botones, etc).

Para indicarle al IDE de Flash donde guardamos nuestras Clases (ClassPath) podemos hacerlo a 2 niveles:
Nivel Proyectos: donde la indicación de ruta es solo para ese proyecto.
Nivel Global: donde la indicación de ruta afectara a todos las peliculas que creemos con nuestro Flash.

Para el primer caso entramos dentro de “Settings” en las propiedades de nuestro proyecto, ahi clickeamos en el boton “Settings” al lado de “ActionScript Version” y en esa ventana agregamos nuestras Classpath (ruta de nuestro disco donde estan las clases).
Para el segundo caso vamos a “Edit” / “Preferences”, seleccionamos la categoria “ActionScript” y clickeamos el boton “ActionScript 3.0 Settings” y en la ventana que nos abre ingresamos nuestras Classpath (ruta de nuestro disco donde estan las clases).

Podemos agregar la cantidad de Classpath que querramos, lo que hara que flash al compilar busque las clases que usamos en nuestro proyecto en todas esas carpetas.
En mi caso suelo usar dos Classpath a nivel Global.
“C:\Proyectos\Clases” que es donde guardo las Clases comunes a todos los proyectos y “./com” que indicaria que busque en una carpeta llama “com” en el directorio donde esta ubicado mi proyecto. En esa carpeta guardo las Clases especificas de ese proyecto.

Clase Main:
Lo que suelo hacer personalmente es usar una Clase “Main”, algo muy común para los que programen en Java u otros lenguajes similares.
Esta Clase va a ser la Clase madre que se ejecute antes que todo y se va a encargar de ejecutar y manejar las demás Clases y todo lo que suceda en mi proyecto (sería como el primer frame lleno de programación clásico en AS2).
Para eso se genera un archivo Main.as y en nuestro .fla de AS3 lo ingresamos en las propiedas del proyecto donde dice “Document Class:”
De esta manjera le indicamos a Flash que Main.as sera nuestra Clase Principal.
Acá les dejo un buen video tutorial sobre este tema.

Asignar una Clase a un MovieClip:
Muchas veces nos puede ser útil asignarle una Clase a un MovieClip, por ejemplo si queremos hacer un Menú dinámico que duplica varias veces un mismo botón. Lo que podemos hacer es tener un MC en la libreria, el cual tendrá asignada una Clase llamada BotonSimple, la cual manejará los eventos de RollOver, Click y lo que querramos sumarle.
De esta forma todos los botones responderán a una misma clase por lo que si hacemos algún cambio afectará a todos lo botones.

Para hacer esto lo que hacemos es darle click derecho al MC en la librería y seleccionar la opción “linkage”, en la ventana que se abre tildamos la opción de “Export for ActionScript” y le escribirmos el nombre de nuestra clase donde dice Class.
También podríamos escribir el nombre donde dice “Base Clase” siempre y cuando la clase que vayamos a usar extienda a un MovieClip.
Esto nos sería útil si queremos asignar una misma clase a varios MC distintos en la librería, ya que el campo “Class” debería tener un valor único.
Vale destacar que si nuestra clase está en un paquete “net/decabeza/utils” deberíamos escribirlo de esta forma “net.decabeza.utils.BotonSimple.as”.

Clases Personalizadas:
También podemos tener Clases personalizadas que usaremos en nuestra Clase “Main.as” que no sea asignadas a un MovieClip.
Por ejemplo podríamos tenes una Clase llamada “LoadJPG.as” la cual cargue un jpg en nuestro proyecto.
Para llamar a esta clase desde Main o desde cualquier lado deberíamos crear una instancia (a no ser que sea una clase estática).

1

var cargador:LoadJPG =  new LoadJPG();

Asi creamos la instancia “cargador” la cual nos permitira ejecutar todos los métodos de nuestra clase.
Eso si, antes de usar una clase personalizada, como cualquier otra clase, en AS3 debemos importar la clase, para eso vamos a escribir una linea similar a esta, arriba de nuestra clase Main.

1

import net.decabeza.utils.LoadJPG

También podríamos importar todas las Clases de un paquete de esta forma

1

import net.decabeza.utils.*

Ahora si estaríamos en condiciones de usar nuestra Clase.

Bueno, hasta ahora esto es todo, faltarían millones de cosas por explicar, pero creo que es un buen comienzo, espero comentarios y preguntas para ir contestando y tal ves de alguna pregunta surja un nuevo artículos básico de AS3.

Saludos!

También te puede interesar:

• Nuevo Video: Creando una Galería de imágenes estilo Picasa
• Usar Google Map con ActionScript 3
• Como funciona BasicView de PaperVision 3D 2.0
• Menú dinámico en XML y ActionScrip 3
• Nuevo Video Tutorial – SWFAddress 2 con AS3

PaperVision3D es un paquete de clases 3D para flash, que nos permite generar una escena 3D en nuestro swf con objetos y camaras. Los cuales podemos mover en sus 3 ejes (X, Y, Z, ya que estamos hablando de 3D).
Esta es una herramienta muy potente que nos permite ampliar muchisimo el mundo de flash y tambien facilitarnos lo que ya existe, como por ejemplo el ya conocido y clasico carrusel 3D (del cual voy a hacer un videoTutorial, cuando este con mas tiempo, implementando PaperVision3D).

Les dejo un ejemplo muy rapido que hice y su codigo para que vean los simple que es su uso:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

//importamos las clases necesarias
import org.papervision3d.scenes.*;
import org.papervision3d.cameras.*;
import org.papervision3d.materials.*;
import org.papervision3d.objects.*;
 
//creamos el contenedor de las escena
var contenedor:Sprite = new Sprite();
contenedor.x = stage.stageWidth * 0.5;
contenedor.y = stage.stageHeight * 0.5;
addChild(contenedor);
 
//creamos la escena3D
var escena:Scene3D = new Scene3D(contenedor);
 
//creamos la camara
var camara:Camera3D = new Camera3D();
camara.zoom = 15;
 
//creamos el material que toma un png de la libreria linkeado como Img
var material1:BitmapAssetMaterial = new BitmapAssetMaterial("Img");
material1.oneSide = false;
material1.smooth = true;
 
//creamos el plano y le agregamos el material
var p1:Plane = new Plane(material1, 200, 200, 3, 3);
escena.addChild(p1);
 
//generamos un enterFrame que le sume 2px a cada eje y rendereamos la camara
addEventListener(Event.ENTER_FRAME, onEnter);
 
function onEnter(e:Event):void
{
	p1.rotationY += 2;
	p1.rotationX += 2;
	p1.rotationZ += 2;
 
	//rendereamos la camara
	escena.renderCamera(camara);
}

Archivos del Ejemplo

Links:
Sitio Oficial
Blog
Descargas

También te puede interesar:

• Como funciona BasicView de PaperVision 3D 2.0
• Nuevo Video: Creando una Galería de imágenes estilo Picasa
• Usando Input text con PaperVision3D
• Realidad Aumentada, una realidad en aumento
• Usar Google Map con ActionScript 3